vbs脚本怎么实现批量转换文件编码

这篇文章主要介绍“vbs脚本怎么实现批量转换文件编码”，在日常操作中，相信很多人在vbs脚本怎么实现批量转换文件编码问题上存在疑惑，小编查阅了各式资料，整理出简单好用的操作方法，希望对大家解答”vbs脚本怎么实现批量转换文件编码”的疑惑有所帮助！接下来，请跟着小编一起来学习吧！

复制代码 代码如下:

'-------------------------------------------------

'函数名称:ReadFile

'作用:利用AdoDb.Stream对象来读取各种格式的文本文件

'-------------------------------------------------

Function ReadFile(FileUrl, CharSet)
    Dim Str
    Set stm = CreateObject("Adodb.Stream")
    stm.Type = 2
    stm.mode = 3
    stm.charset = CharSet
    stm.Open
    stm.loadfromfile FileUrl
    Str = stm.readtext
    stm.Close
    Set stm = Nothing
    ReadFile = Str
End Function

我们使用ReadFile函数读取文件，其中FileUrl指定文件的路径，CharSet指定文件的原始编码格式，使用adodb.stream对象读取文件内容到Str。

复制代码 代码如下:

'-------------------------------------------------

'函数名称:WriteToFile

'作用:利用AdoDb.Stream对象来写入各种格式的文本文件

'-------------------------------------------------

Function WriteToFile (FileUrl, Str, CharSet)
    Set stm = CreateObject("Adodb.Stream")
    stm.Type = 2
    stm.mode = 3
    stm.charset = CharSet
    stm.Open
    stm.WriteText Str
    stm.SaveToFile FileUrl, 2
    stm.flush
    stm.Close
    Set stm = Nothing
End Function

然后使用WriteToFile将Str写回原文件FileUrl，并设定新的编码CharSet。

复制代码 代码如下:

'-------------------------------------------------

'函数名称:ConvertFile

'作用:将一个文件进行编码转换

'-------------------------------------------------

Function ConvertFile(FileUrl)
    Call WriteToFile(FileUrl, ReadFile(FileUrl, SrcCode), DestCode)
End Function

这样ConvertFile对上述两个函数封装，实现文件FileUrl的编码转换，其中原始编码SrcCode与目的编码DestCode为全局变量。

如果仅对一个文件进行编码转换，我们不必这么大费周章。我们希望能对任意的文件或文件夹内的所有文件进行编码转换，达到批量转换的目的。

复制代码 代码如下:

'-------------------------------------------------

'函数名称:ConvertDir

'作用:将任意目录内的文件进行编码转换

'-------------------------------------------------

Function ConvertDir(DirUrl)
    If fs.FileExists(DirUrl) Then
       Call ConvertFile(DirUrl)
    Else
       Call SearchDir(DirUrl)
    End If
End Function

函数ConvertDir对任意路径的文件/文件夹进行编码转换，使用scripting.filesystemobject对象的FileExists函数判断路径对应的是文件还是文件夹，如果是文件则直接调用ConvertFile进行编码转换，否则调用SearchDir处理文件夹。

复制代码 代码如下:

'-------------------------------------------------

'函数名称:SearchDir

'作用:递归查找目录内的文件，进行编码转换

'-------------------------------------------------

Function SearchDir(path)  
    Set folder = fs.getfolder(path)
    Set subfolders = folder.subfolders
    Set Files = folder.Files  
    For Each i In Files
       Call ConvertFile(i.path)
    Next  
    For Each j In subfolders      
       Call SearchDir(j.path)
    Next
End Function

函数SearchDir是递归的，首先调用getfolder创建文件夹对象，然后取出文件夹内的子文件夹集合subfolders和子文件集合files。对于每个子文件，直接调用ConvertFile进行编码转换即可，而对于每个子文件夹，则递归调用SearchDir重复处理。

复制代码 代码如下:

'-------------------------------------------------

'设置编码：默认 utf-8  --> gb2312

'-------------------------------------------------

SrcCode="utf-8"
DestCode="gb2312"

'-------------------------------------------------

'解析参数

'-------------------------------------------------

Set fs = CreateObject("scripting.filesystemobject")
Set objArgs = WScript.Arguments
If objArgs.Count>0 Then
    For I = 0 To objArgs.Count - 1
       FileUrl = objArgs(I)
       Call ConvertDir(FileUrl)
    Next
Else
    MsgBox "没有文件/文件夹被拖入！"
    wscript.quit
End If

MsgBox "转换成功！"

最后通过解析脚本文件的参数，由于每个参数对应一个文件/文件夹的路径，将之传递给ConvertDir即可。这里默认的是将UTF-8编码转化为GB2312编码，读者可以根据自身需要自行修改。

将上述代码保存为ConvertCode.vbs，只需要将任意多个文件选中拖动到该脚本文件上即可。或者使用命令行。

复制代码 代码如下:

> ConvertCode.vbs [filepath]

需要注意的是文件编码是就地转换的，在转换之前最好将原文件/文件夹进行备份。

最后附上脚本文件的所有代码。

复制代码 代码如下:

'/*===========================================================' * Intro        把要转换的多个文件/文件夹拖到该文件上即可' * FileName     ConvertCode.vbs' * Author       Florian' * Version      v1.0' * LastModify  2014-06-11 00:39:58' *==========================================================*/
'-------------------------------------------------'设置编码：默认    utf-8    -->    gb2312'-------------------------------------------------
SrcCode="utf-8"DestCode="gb2312"
'-------------------------------------------------'解析参数'-------------------------------------------------
Set fs = CreateObject("scripting.filesystemobject")Set objArgs = WScript.ArgumentsIf objArgs.Count>0 Then    For I = 0 To objArgs.Count - 1        FileUrl = objArgs(I)        Call ConvertDir(FileUrl)    NextElse    MsgBox "没有文件/文件夹被拖入！"    wscript.quitEnd IfMsgBox    "转换成功！"
'-------------------------------------------------'函数名称:ConvertDir'作用:将任意目录内的文件进行编码转换'-------------------------------------------------
Function ConvertDir(DirUrl)    If fs.FileExists(DirUrl) Then          Call ConvertFile(DirUrl)    Else        Call SearchDir(DirUrl)    End IfEnd Function
'-------------------------------------------------'函数名称:SearchDir'作用:递归查找目录内的文件，进行编码转换'-------------------------------------------------
Function SearchDir(path)        Set folder = fs.getfolder(path)    Set subfolders = folder.subfolders    Set Files = folder.Files        For Each i In Files        Call ConvertFile(i.path)    Next        For Each j In subfolders                Call SearchDir(j.path)    NextEnd Function
'-------------------------------------------------'函数名称:ConvertFile'作用:将一个文件进行编码转换'-------------------------------------------------
Function ConvertFile(FileUrl)    Call WriteToFile(FileUrl, ReadFile(FileUrl, SrcCode), DestCode)End Function
'-------------------------------------------------'函数名称:ReadFile'作用:利用AdoDb.Stream对象来读取各种格式的文本文件'-------------------------------------------------
Function ReadFile(FileUrl, CharSet)    Dim Str    Set stm = CreateObject("Adodb.Stream")    stm.Type = 2    stm.mode = 3    stm.charset = CharSet    stm.Open    stm.loadfromfile FileUrl    Str = stm.readtext    stm.Close    Set stm = Nothing    ReadFile = StrEnd Function
'-------------------------------------------------'函数名称:WriteToFile'作用:利用AdoDb.Stream对象来写入各种格式的文本文件'-------------------------------------------------
Function WriteToFile (FileUrl, Str, CharSet)    Set stm = CreateObject("Adodb.Stream")    stm.Type = 2    stm.mode = 3    stm.charset = CharSet    stm.Open    stm.WriteText Str    stm.SaveToFile FileUrl, 2    stm.flush    stm.Close    Set stm = NothingEnd FunctionView Code

到此，关于“vbs脚本怎么实现批量转换文件编码”的学习就结束了，希望能够解决大家的疑惑。理论与实践的搭配能更好的帮助大家学习，快去试试吧！若想继续学习更多相关知识，请继续关注亿速云网站，小编会继续努力为大家带来更多实用的文章！